@echo off
rem =====================================================================
rem  Stammzertifikat.cmd  -  STAMMCA-V1 (12.10.2026)
rem  Startet Stammzertifikat.ps1.
rem    Doppelklick:   als Verwalter (mit Nachfrage), Fenster bleibt offen
rem    -Still:        fuer den nachher-Schritt des Updaters - KEINE
rem                   Nachfrage, KEIN pause (der Updater wartet sonst ewig)
rem =====================================================================

setlocal
set "HIER=%~dp0"
set "SKRIPT=%HIER%Stammzertifikat.ps1"
set "STILL="
echo %* | find /i "-Still" >nul && set "STILL=1"

if not exist "%SKRIPT%" (
    echo   FEHLER: Stammzertifikat.ps1 liegt nicht neben dieser Datei.
    if not defined STILL pause
    exit /b 4
)

if defined STILL goto :laufen

net session >nul 2>&1
if errorlevel 1 (
    echo.
    echo   Es braucht Verwalterrechte - starte neu mit Nachfrage...
    if "%*"=="" (
        powershell -NoProfile -Command "Start-Process -Verb RunAs -FilePath '%~f0'"
    ) else (
        powershell -NoProfile -Command "Start-Process -Verb RunAs -FilePath '%~f0' -ArgumentList '%*'"
    )
    exit /b 0
)

:laufen
powershell -NoProfile -ExecutionPolicy Bypass -File "%SKRIPT%" %*
set "RC=%ERRORLEVEL%"
if not defined STILL (
    echo.
    pause
)
endlocal & exit /b %RC%